Примеры программ обработки данных

Пример 1. Заполнить массив 1100Н-110FH внешнего ОЗУ данных константой со входов порта Р1. Транслировать программу, начиная с адреса 100Н.

1 0100 ORG 100H

2 0100 901100 MOV DPTR,#1100H

3 0103 7910 MOV R1,#16

4 0105 E590 MOV A,P1

5 0107 F0 M1: MOVX @DPTR,A

6 0108 A3 INC DPTR

7 0109 D9FC DJNZ R1,M1

8 010B END

Для обращения к ВПД используется регистр указатель данных DPTR. Счетчик числа элементов массива выполнен на регистре R1. В четвертой строке программы второй байт берется равным прямому адресу порта Р1. В седьмой строке второй байт равен относительному смещению от адреса следующей команды до адреса, соответствующего метке М1 (дополнительный код числа минус 4).

Пример 2. Произведение П цифр двухразрядного десятичного числа, находящегося в аккумуляторе в двоично-десятичном коде, возвратить в аккумулятор также в двоично-десятичном коде. Транслировать программу, начиная с нулевой ячейки.

1 0000 75F010 MOV B,#10H ; Распаковка цифр числа

2 0003 84 DIV AB ; в регистры А и В

3 0004 A4 MUL AB ; Двоичный код П в А

4 0005 75F00A MOV B,#10 ; П делится на 10. А содержит

5 0008 84 DIV AB ; цифру десятков, В — остаток

6 0009 C4 SWAP A ; Цифры произведения в

7 000A 45F0 ORL A,B ; упакованном формате

8 000C END

Сначала исходное число делится на 16 (процессор при выполнении команды деления считает, что содержимое аккумулятора соответствует двоичному числу). Старшая цифра числа попадает в А, младшая — в В. Затем в аккумуляторе формируется двоичный код их произведения. Далее делением на 10 реализуется преобразование произведения в двоично-десятичный формат. Второй байт команды в седьмой строке соответствует прямому адресу регистра В.

Пример 3. Скопировать массив РПД 20Н-2FH на новое место, начиная с ячейки 40Н.

MOV R0,#20H ; Начальный адрес первого массива

MOV R1,#40H ; Начальный адрес второго массива

MOV R2,#16 ; Число элементов массива

M1: MOV A,@R0 ; Пересылка очередного элемента

MOV @R1,A ; массива

INC R0 ; Организация цикла

INC R1 ; копирования

DJNZ R2,M1 ; элементов массива

Для обработки элементов массива в цикле всегда удобно использовать косвенную адресацию, которая в данном примере реализуется с помощью регистров R0 и R1. Другие регистры общего назначения для этой цели использовать нельзя. Директива END в данном и последующих примерах опущена.

Пример 4. Наибольшее число массива 8-разрядных чисел без знака в РПД (20Н-2FH) поместить в ячейку 30Н.

MAX EQU 30H ; Директива ассемблера

MOV R0,#20H ; Указатель памяти

MOV R1,#16 ; Счетчик числа элементов

MOV MAX,#0 ; Обнуление ячейки результата

M1: MOV A,@R0 ; Сравнение очередного элемента

CJNE A,MAX,$+3 ; массива с ячейкой результата

JC M2 ; Переход, если меньше или равно

MOV MAX,A ; Замена, если больше

M2: INC R0 ; Организация цикла

DJNZ R1,M1 ; просмотра элементов массива

С помощью директивы EQU ячейке резидентной памяти данных с адресом 30Н присвоено символическое имя МАХ, которое неоднократно используется в тексте программы, улучшая ее «читаемость». Присвоение уникальных имен всем переменным, используемым при выполнении задачи — прием, широко используемый в практике программирования на языке ассемблера.

В данном примере результатом выполнения команды сравнения является установка или сброс флага переноса С. Команда тестирования этого флага выполняется не зависимо от того, равно содержимое аккумулятора содержимому ячейки МАХ или нет.

Пример 5.Сравнить содержимое аккумулятора с константой 100 и выполнить следующие действия:

если А=100, то перейти на метку М1;

если А<100, то перейти на метку М2;

если А>100, то перейти на метку М3.

CJNE A,#100,$+6

LJMP M1 ; Переход, если А=100

JC M2 ; Переход, если А<100

M3: ……………….. ; Выполнение условия А>100

Если содержимое аккумулятора не равно 100, то дополнительно тестируется флаг переноса С. Он устанавливается в единицу при выполнении условия А<100 и в ноль при А>100.

Пример 6.Преобразовать двоичное число без знака, находящееся в аккумуляторе, в двоично-десятичное и поместить его в DPTR.

MOV B,#100 ; Делим на 100 для определения

DIV AB ; числа сотен

MOV DPH,A ;

MOV A,#10 ; Делим на 10 для определения

XCH A,B ; числа десятков

DIV AB ;

SWAP A ; Обмен полубайтов аккумулятора

ADD A,B ; Добавляем единицы

MOV DPL,A ;

Пример 7. Показать структуру построения программы, использующей аппаратное прерывание по фронту INT0.

ORG 0 ; Начало программы

SJMP MAIN ; Переход к основной программе

ORG 0003Н ; Вектор прерывания

AJMP SUBR ; Переход к п/п обслуживания

MAIN: MOV SP,#100 ; Настройка указателя стека

SETB EA ; Сброс блокировки прерываний

SETB EX0 ; Разрешение прерывания INT0

SETB IT0 ; Бит прерывания по фронту

............................ ; Текст основной программы

ORG 800H ; Начало п/п прерывания

SUBR: PUSH PSW ; Сохранение в стеке

PUSH ACC ; содержимого

PUSH B ; регистров

PUSH DPL ;

PUSH DPH ;

SETB RS0 ; Выбор первого банка РОН

CLR RS1

............................ ; Текст подпрограммы

POP DPH ; Восстановление из стека

POP DPL ; содержимого

POP B ; регистров

POP ACC ;

POP PSW ;

RETI ; Возврат из п/п прерывания

Предполагается регистры первого банка РОН использовать только в подпрограмме обслуживания аппаратного прерывания. Для этого необходимо модифицировать содержимое указателя стека, так как после сброса он настроен на область РПД, занимаемую банком РОН1.

Прерывание происходит всегда неожиданно для основной программы, поэтому при его обслуживании необходимо сохранить содержимое PSW и всех регистров, используемых подпрограммой. В данном примере предполагается использовать в подпрограмме регистры A, B и DPTR.

Текст подпрограммы обслуживания прерываний можно располагать в любом удобном месте программы. Так как при наличии запроса на прерывание управление передается ячейке с адресом 0003Н, в этой ячейке записывается команда безусловного перехода к выбранному адресу подпрограммы обслуживания. Если после выполнения команды RETI на входе INT0 сохраняется 0, подпрограмма обслуживания не будет выполняться повторно, так как установлен бит прерывания по фронту IT0.

Пример 8. На линии Р1.0 — Р1.3 поступают сигналы X, Y, Z и V от датчиков. Выдать на линию Р1.4 этого порта сигнал в соответствии с логическим выражением F=X(Y+Z)+ .

1 0090 X EQU P1.0

2 0091 Y EQU P1.1

3 0092 Z EQU P1.2

4 0093 V EQU P1.3

5 0094 F EQU P1.4

6 0000 A291 MOV C,Y

7 0002 7292 ORL C,Z

8 0004 8290 ANL C,X

9 0006 A093 ORL C,/V

10 0008 9294 MOV F,C

11 000A END

Контроллер МК51 имеет битовый процессор и позволяет проводить логические операции и операции тестирования с отдельными битами. Прямую адресацию имеют 128 флагов пользователя в РПД и биты 11 регистров специальных функций. В РПД можно организовать карту опроса 128 датчиков и эффективно обрабатывать эту информацию с использованием команд битового процессора.

В контроллерах, не имеющих битового процессора (К580, МК48), каждая команда логической обработки бита требует загрузки байта в аккумулятор, выполнения команд логической обработки байтов, маскирования и команд условных переходов. Поэтому реализация булевых функций микроконтроллером МК51 осуществляется значительно проще и быстрее.

На языке ассемблера битовый операнд можно записывать, используя символические имена бита или регистра, либо прямые адреса бита или регистра. Вот примеры записи команды выбора первого банка РОН:

SETB RS0 ; Используется символическое имя бита

SETB PSW.3 ; Используется символическое имя регистра

SETB 0D0H.3 ; Используется прямой адрес регистра

SETB 0D3H ; Используется прямой адрес бита

Независимо от формы записи команды второй байт при трансляции соответствует прямому адресу бита (D3).

Логические операции обработки битов реализуются с участием триггера переноса С, который для битовых операндов выполняет такую же роль, как аккумулятор в командах арифметических и логических операций с байтами.

Пример 9. Организовать задержку длительностью 50 мс на микроконтроллере К1830ВЕ51 с использованием таймера, прерываний и режима холостого хода.

1 000B ORG 000BH ; Вектор прерывания

2 000B C28C CLR TR0 ; Останов Т/С0

3 000D 32 RETI ; Возврат из п/п

4 0100 ORG 100H ; Начало программы

5 0100 D2AF MAIN: SETB EA ; Снятие блокировки

6 0102 758901 MOV TMOD,#01H ; Режим 1 Т/С0

7 0105 758AB0 MOV TL0,#LOW(NOT(50000)+1)

8 0108 758C3C MOV TH0,#HIGH(NOT(50000)+1)

9 010B D28C SETB TR0 ; Старт Т/С0

10 010D D2A9 SETB IE.1 ; Разрешение прерываний

11 010F 758701 MOV PCON,#01H ; Режим ХХ

12 0112 NEXT: ............. ; Продолжение программы

При использовании таймера в режиме 1 (кварц на 12 МГц) можно получать задержки до 65536 мкс. Включение и выключение таймера осуществляется установкой и сбросом бита TR0 (TCON.4). Чтобы переполнение таймера произошло через 50 мс, в его регистры необходимо загрузить дополнительный код числа 50000. Формирование дополнительного кода, загрузку младшего байта в TL0, а старшего в ТН0, выполняет ассемблер.

Микроконтроллеры серии К1830, выполненные по КМОП-технологии, можно перевести в режим холостого хода установкой нулевого бита регистра РCON (IDL). В этом режиме блокируются функциональные узлы центрального процессора, что уменьшает энергопотребление до 4 мА. Сохраняется содержимое SP, PC, PSW, A и других регистров и РПД. Активизация любого разрешенного прерывания (а также аппаратный сброс микроконтроллера) заканчивает режим ХХ. После выполнения команды RETI будет исполнена команда, которая следует за командой, переведшей МК в режим холостого хода.

Установкой первого бита регистра PCON (PD) можно перевести МК в режим микропотребления (напряжение питания может быть уменьшено до 2 В, потребляемый ток — 50 мкА). В этом режиме прекращается работа всех узлов микроконтроллера, но сохраняется содержимое ОЗУ. Вывести МК из режима микропотребления можно только аппаратным сбросом (RST=1).

У микроконтроллеров серии К1816 используется только старший бит регистра PCON (SMOD). Установка этого бита удваивает скорость передачи при работе последовательного порта.

Пример 10. Подсчитать число импульсов, поступающих на вход Т1 (Р3.5) за заданный промежуток времени (10 мс). Текст программы разместить с адреса 1000Н. Результат сформировать в DPTR.

1 D8F0 TIME EQU NOT(10000)+1

2 1000 ORG 1000H

3 1000 758951 MOV TMOD,#01010001B

4 1003 E4 CLR A

5 1004 F58D MOV TH1,A

6 1006 F58B MOV TL1,A

7 1008 758CD8 MOV TH0,#HIGH(TIME)

8 100B 758AF0 MOV TL0,#LOW(TIME)

9 100E 438850 ORL TCON,#50H

10 1011 108D02 M1: JBC TF0,M2

11 1014 80FB SJMP M1

12 1016 858D83 M2: MOV DPH,TH1

13 1019 858B82 MOV DPL,TL1

14 101C END

Управляющее слово в третьей строке программы настраивает Т/С0 на работу в режиме 16-битового таймера, Т/С1 — в режиме 16-битового счетчика событий. В регистры таймера перед пуском загружается дополнительный код числа 10000, регистры счетчика событий обнуляются. Команда в девятой строке одновременно осуществляет старт Т/С0 и Т/С1. Счет импульсов происходит до переполнения Т/С0, после чего содержимое Т/С1 переписывается в DPTR. Команда JBC сбрасывает флаг TF0.

Пример 11. Спроектировать устройство для измерения длительности одиночного импульса, поступающего на вход INT0 (P3.2) микроконтроллера К1830ВЕ31 (рис. 6.1).

Информация о длительности импульса (число до 9999 мкс) выводится на линии портов Р2 (старший байт) и Р1 (младший байт) в двоично-десятичном коде. Сигнал управления работой внешнего индикатора сформирован на линии Р3.0. По сигналу ALE адрес очередного байта команд фиксируется с порта Р0 в регистре RG (микросхема К580ИР82), а по сигналу РМЕ этот байт поступает в микроконтроллер из внешнего ПЗУ (микросхема К556РТ5) через тот же порт Р0. Запуск устройства на измерение импульса производится нажатием кнопки «Измерение», вызывающим сброс микроконтроллера и повторный старт программы, начиная с нулевого адреса. При этом автоматически происходит обнуление регистров таймера Т/С0.

К микроконтроллеру, используемому для решения поставленной задачи, должен подключаться кварцевый резонатор на 12 МГц, при котором на вход таймера при положительном уровне на входе INT0 поступают импульсы с частотой 1 МГц. По окончании измеряемого импульса его длительность (она не должна превышать 10 мс) в микросекундах фиксируется в двоичном коде в регистрах ТН0 и ТL0.

; Прикладная программа измерителя

; длительности одиночного импульса

M1:

Преобразование двухбайтового двоичного в двухбайтовое двоично-десятичное число осуществляется методом двух счетчиков. Суммирующий двоично-десятичный счетчик реализован в портах Р1, Р2, вычитающий двоичный — на регистрах таймера TL0, TH0. Процесс преобразования заканчивается при обнулении двоичного счетчика.

Пример 12. Построить на микроконтроллере К1830ВЕ51 электронные часы с индикацией часов, минут и секунд реального времени (рис. 6.2). Прикладная программа приведена в программе выполнения лабораторной работы №2. Информация с двоично-десятичных счетчиков часов, минут и секунд, реализованных в портах Р0, Р1 и Р2, поступает на цифровые семисегментные индикаторы через преобразователи кода.

Пример 13. Сформировать на выходе WR импульс логического нуля длительностью 50 мкс.

Ниже приводится фрагмент программы, реализующий эту функцию, с указанием времени выполнения отдельных команд (при частоте кварца 12 МГц один машинный цикл составляет 1 мкс):

CLR WR ; 1 машинный цикл

MOV R7,#24 ; 1 машинный цикл

DJNZ R7,$ ; 2 машинных цикла

SEТВ WR ; 1 машинный цикл

Время между сбросом и установкой бита WR (P3.6) составит примерно 50 мкс, так как команда DJNZ выполнится 24 раза.

Пример 14. Разработать программу преобразования кода 10 элементов массива, находящегося в резидентной памяти микроконтроллера К1816ВЕ51, из двоично-десятичного в двоичный (байтовая информация).

Считаем, что массив занимает ячейки памяти данных на кристалле с 50 по 59. Используем команду умножения байтов. Подробный комментарий помещен в текст программы.

MOV R0,#50 ; Начальный адрес массива

MOV R7,#10 ; Число элементов массива

M1: MOV A,@R0 ; Выделение числа

SWAP A ; десятков

ANL A,#0FH

MOV B,#10 ; 10 в расширитель аккумулятора

MUL AB

MOV B,A

MOV A,@R0 ; Выделение единиц

ANL A,#0FH

ADD A,B ; Формирование двоичного числа

MOV @R0,A ; Замена элемента массива

INC R0 ; Наращивание адреса

DJNZ R7,M1 ; Цикл обработки массива

Время между сбросом и установкой бита WR (P3.6) составит примерно 50 мкс, так как команда DJNZ выполнится 24 раза.

Пример 15. Разрешить внешние прерывания по фронту сигналов на входах INT0 и INT1 и прерывание по переполнению таймера/счетчика Т/С1.

Прерыванию по Т/С1 присвоить высший приоритет. Стек организовать начиная с сотой ячейки РПД.

Инициализацию системы прерываний выполним установкой в 1 соответствующих битов регистров IE, IP, TCON. После системного сброса эти регистры обнулены.

MOV IE,#10001101B ; Установка битов EA, ET1, EX1, EX0

; регистра масок прерываний

SETB PT1 ; Высший приоритет Т/С1 установкой

; бита IP.3 регистра приоритетов

SETB IT0 ; Прерывания по фронту INT0

SETB IT1 ; Прерывания по фронту INT1

MOV SP,#99 ; Модификация указателя стека

Установка бита ЕА снимает общую блокировку прерываний, которая действует после системного сброса. После выполнения первой команды разрешены три прерывания (в порядке убывания приоритетов): внешнее аппаратное по входу INT0 с вектором 03Н, внешнее аппаратное по входу INT1 с вектором 13Н и прерывание по таймеру/счетчику Т/С1 с вектором 1ВН. После выполнения второй команды прерыванию от Т/С1 присваивается высокий уровень приоритета. Подпрограмма обслуживания этого прерывания не может быть прервана другим источником прерываний. В то же время установка флага TF1 вызовет переход к вектору 1ВН даже при выполнении подпрограмм обслуживания внешних прерываний. Все подпрограммы прерываний должны заканчиваться командой RETI (при обслуживании прерываний действует блокировка прерываний такого же уровня, которую команда RET не снимает). После системного сброса в указатель стека заносится число 7Н. Последняя команда модифицирует его так, что при вызове подпрограммы адрес возврата запишется в сотую (младший байт) и сто первую ячейки РПД (старший байт).

Пример 16. Получить на линейке светодиодов, подключенных к линиям порта Р1, световой эффект бегущего огонька.

Нагрузочной способности порта Р1 недостаточно для непосредственного включения светодиодов (выходной ток высокого уровня сигналов — 80 мкА, выходной ток низкого уровня сигналов — 1,6 мА, в то время как нормальное свечение светодиода обеспечивается при токе порядка 5–10 мА). В качестве усилителя тока можно использовать преобразователи уровня или логические элементы НЕ (см. рис. 8.2).

Алгоритм получения эффекта «бегущая единица» состоит в организации цикла последовательных операций: вывод 1 в одну из линий порта, организация задержки, смена адреса активной линии порта. Смену адреса проще всего получить путем сдвига кодовой единицы в аккумуляторе. Задержка должна составлять десятые доли секунды. При частоте переключений больше 24 Гц глазу человека будет казаться, что все светодиоды горят непрерывно. С учетом этих замечаний построена приводимая ниже программа.

MOV A,#1 ; 1

M1: MOV P1,A ; 2

DELAY: DJNZ R0,$ ; 2

DJNZ R1,DELAY ; 2

RL A ; 1

SJMP M1 ; 2

В поле примечания приведено время выполнения команд программы в машинных циклах (при частоте кварцевого резонатора 12 МГц один машинный цикл равен 1 мкс). После окончания временной задержки регистры R0 и R1 обнулены. Таким образом, каждый раз при реализации временной задержки команда DJNZ R1,DELAY выполняется 256 раз, а команда DJNZ R0,$ — 256² раз.

Суммарное время задержки составляет 5+2(256+256²) = = 131589 мкс.

Пример 17. Подсчитать количество символов в первом предложении текста, размещенного в РПД начиная с ячейки 20Н (включая пробелы). Результат сформировать в регистре R7 в двоично–десятичном коде.

Решение.Ниже приведен текст программы на языке ассемблера с подробным комментарием:

MOV R0,#20H ; начало массива

CLR A ; очистка счетчика

M1: CJNE @R0,#’.’,M2 ; сравнение с кодом точки 2ЕН

SJMP EXIT ; закончить обработку массива

M2: INC R0 ; наращивание указателя памяти

ADD A,#1 ; двоично–десятичный

DA A ; счетчик в аккумуляторе

SJMP M1 ; организация цикла

EXIT: MOV R7,A ; результат в R7

Используется косвенная адресация элементов массива.Двоично-десятичный счетчик числа символов организован в аккумуляторе с использованием команды десятичной коррекции.

После ассемблирования программы сформирован файл листинга прикладной программы massiv.lst, приведенный ниже.

########################################################

# #

# Micro Series 8051 Assembler V1.80/MD2 11/Oct/07 11:21:50 #

# #

# Source = massiv.asm #

# List = massiv.lst #

# Object = massiv.r03 #

# Options = #

# #

# (c) Copyright IAR Systems 1985 #

########################################################

1 0000 7820 mov r0,#20H

2 0002 E4 clr a

3 0003 B62E02 m1: cjne @r0,#'.',m2

4 0006 8006 sjmp exit

5 0008 08 m2: inc r0

6 0009 2401 add a,#1

7 000B D4 da a

8 000C 80F5 sjmp m1

9 000E FF exit: mov r7,a

10 000F end

Errors: None ##########

Bytes: 15 # massiv #

CRC: F3A2 ##########