Порядок выполнения лабораторной работы. 1. Войти в среду Visual Basic и загрузить (открыть) проект Lab6
1. Войти в среду Visual Basic и загрузить (открыть) проект Lab6. Изменить его имя на Lab7. Сохранить все компоненты проекта, а затем весь проект под новым именем, соответствующему номеру лабораторной работы и требованиям, изложенным в разделе 4.
2.Нажать Ctrl + E для вызова редактора меню.
3. Создать пункт меню Файл. Для этого в окне Caption (Заголовок) задать заголовок меню – «&файл». Символ & (амперсанд) перед буквой Ф указывает на возможность использования горячей клавиши Аlt+Ф. В окне Name(Имя) задать имя элемента управления, создаваемого редактором меню для этого пункта меню – mnuFile.
В нижней части меню появится строка с только что созданным пунктом.
4. Щелкнуть на кнопке Next (Следующий), чтобы проинформировать редактор меню о необходимости добавить в меню следующий пункт. Выделенная подсветкой полоса в нижней части окна Menu Editor переходит вниз к следующей строке для подготовки к следующему пункту меню.
5.Создать подпункт меню «Открыть» с именем mnuFileOpen, как сказано в пункте 3. Затем щелкнуть на управляющей кнопке со стрелкой вправо для указания, что создаваемый пункт меню является подпунктом вышестоящего.
6. Аналогично создать подпункты mnuFileSave (сохранить) и mnuFileExit (выход) пункта mnuFile.
7.Создать пункт-меню mnuView (вид) с подпунктами mnuViewGraph (показывать график), mnuViewColor (цвет графика) и mnuViewFont (шрифт). При создании подпункта mnuViewGraph в окне редактора меню установить флажок Checked (Поверка). Этот флажок задает наличие «галочки» рядом с подпунктом меню, указывая, что пункт действует как переключатель. «Галочка» соответствует значению «истина» свойства Checked элемента управления mnuViewGraph.
8.Создать пункты меню mnuHelp (помощь) и mnuExit (выход).
9. Связать каждую командную кнопку меню (конечный пункт) с кодом обработки события Click. Для добавления кода необходимо выбрать требуемую команду в процессе разработки и щелкнуть на конечном пункте. При разработке процедур нужно использовать уже применяемый в прошлой работе элемент управления Common Dialog Box для открытия и сохранения файла. Кроме того, его необходимо использовать для выбора цвета и шрифтов. После ввода всех процедур должен получиться примерно следующий код:
Private Sub mnuFileOpen_Click()
'Обработка события Выбор команды Открыть из меню Файл
'
Dim Str As String
cdb.DialogTitle = "Открыть файл"
'Определили заголовок для окна диалога элемента управления
'Command Dialog Box
cdb.ShowOpen
'Вызвали метод Открыть элемента управления
'Command Dialog Box для вывода на экран стандартного
'окна диалога. Результатом его работы будет
'выбранный пользователем путь к файлу (диск-каталог) -
'свойство InitDir и имя файла - свойство FileName
Str = cdb.InitDir & cdb.FileName
Open Str For Input As #1
'Открыли файл на диске. Путь (диск-каталог) и имя файла
'получено от элемента управления Command Dialog Box
'после выполнения его метода Открыть
Input #1, n, XMin, XMax, YMin, YMax
'Прочитали параметры таблицы значений из первой записи
ReDim MX(n), MY(n)
'Установили фактический размер массивов
For i = 0 To n
Input #1, MX(i), MY(i)
Next
'В цикле прочитали из файла всю таблицу значений
Close #1
'Закрыли файл
PrntFunc
Form2.Visible = True
Form2.SetFocus
Graph
Form3.Visible = True
Form3.SetFocus
'Вызвали процедуры печати таблицы значений и рисования
'графика. При этом сделали видимыми формы и поместили
'их на передний план, передав фокус.
End Sub
Private Sub mnuFileSave_Click()
'Обработка события Выбор из меню команды Сохранить
'
Dim Str As String
cdb.DialogTitle = "Сохранить файл"
'Определили заголовок для окна диалога элемента управления
'Command Dialog Box
cdb.ShowSave
'Вызвали метод Сохранить элемента управления
'Command Dialog Box для вывода на экран стандартного
'окна диалога. Результатом его работы будет
'выбранный пользователем путь к файлу (диск-каталог) -
'свойство InitDir и имя файла - свойство FileName
Str = cdb.InitDir & cdb.FileName
Open Str For Output As #1
'Открыли файл на диске. Путь (диск-каталог) и имя файла
'получено от элемента управления Command Dialog Box
'после выполнения его метода Сохранить
Write #1, n, XMin, XMax, YMin, YMax
'Параметры таблицы значений вывели в первую запись
For i = 0 To n
Write #1, MX(i), MY(i)
Next
'В цикле вывели в файл всю таблицу значений
Close #1
'Закрыли файл
End Sub
Private Sub mnuViewColor_Click()
'Обработка события команды Цвет графика
'из меню команды Вид
'
Dim Str As String
cdb.DialogTitle = "Цвет графика"
'Определили заголовок для окна диалога элемента управления
'Command Dialog Box
cdb.Flags = 2
' Установили флаг, предписывающий показывать расширенное окно
' цветовой палитры. Помещает колонку ДОБАВИТЬ В НАБОР и
' цветовое поле для с маркером и линейкой назначения оттенка
' для добавления цвета в поля ДОПОЛНИТЕЛЬНЫЕ ОТТЕНКИ.
cdb.ShowColor
'Вызвали метод ShowColor элемента управления
'Command Dialog Box для вывода на экран стандартного
'окна диалога. Результатом его работы будет
'выбранный пользователем из палитры цвет в свойстве Color
'этого элемента. Значение этого свойства можно присваивать
'свойствам других элементов. Для изменения цвета графика
'присвоим это значение свойству ForeColor формы.
Form3.ForeColor = cdb.Color
If n <> 0 Then Graph
'Вызвали подпрограмму для перерисовки графика
End Sub
Private Sub mnuViewFont_Click()
'Обработка события Выбор команды Шрифт
'из меню Вид
Dim Str As String
cdb.DialogTitle = "Шрифт"
'Определили заголовок для окна диалога элемента управления
'Command Dialog Box
cdb.Flags = 1 + 256
'Установили флаг, который обеспечивает показ экранных
'шрифтов (1) и Показывает в окне диалога элементы, задающие
'эффект подчеркивания, зачеркивания и цвета.
cdb.ShowFont
'Вызвали метод ShowColor элемента управления
'Command Dialog Box для вывода на экран стандартного
'окна диалога. Результатом его работы будет
'выбранный пользователем шрифт
Form2.Font.Size = cdb.FontSize
Form2.Font.Name = cdb.FontName
Form2.Font.Underline = cdb.FontUnderline
Form2.Font.Bold = cdb.FontBold
Form2.Font.Italic = cdb.FontItalic
Form2.ForeColor = cdb.Color
'Параметры шрифта присвоили соответствующим свойствам
'формы Form2 /таблица значений/
PrntFunc
'Вызвали процедуру перерисовки формы Form2 /таблица значений/
End Sub
Private Sub mnuViewGraf_Click()
'Обработка события Выбор команды Показывать график
If mnuViewGraf.Checked = False Then
mnuViewGraf.Checked = True
Form3.Visible = True
Else
mnuViewGraf.Checked = False
Form3.Visible = False
End If
End Sub
Private Sub mnuViewHelp_Click()
MsgBox "Извините, Помощь отсутствует"
End Sub
Private Sub mnuExit_Click()
'Обработка события Выбор команды Выход из меню
Unload Form2
Unload Form3
End
End Sub
Private Sub mnuFileExit_Click()
'Обработка события Выбор команды Выход из меню Файл
Unload Form2
Unload Form3
End
End Sub
Private Sub Xnac_LostFocus()
If Not IsNumeric(Xnac) Then
Xnac.SetFocus
MsgBox "Неверное значение: не цифра"
End If
End Sub
Private Sub Xkon_LostFocus()
If Not IsNumeric(Xkon) Then
Xkon.SetFocus
MsgBox "Неверное значение: не цифра"
End If
End Sub
Private Sub hX_LostFocus()
If Not IsNumeric(hX) Then
hX.SetFocus
MsgBox "Неверное значение: не цифра"
End If
End Sub
Private Sub A_LostFocus()
If Not IsNumeric(A) Then
A.SetFocus
MsgBox "Неверное значение: не цифра"
End If
End Sub
Private Sub Command1_Click()
'Обработка события Щелчок для командной кнопки Расчет
'Последовательно вызываются процедуры:
' * - табулирования
' * - печать таблицы значений
' * - рисование графика функции
TabFunc Xnac, Xkon, hX
Form2.Visible = True
Form2.SetFocus
PrntFunc
If mnuViewGraf.Checked = True Then
Form3.Visible = True
Form3.SetFocus
End If
Graph
End Sub
Private Sub Command2_Click()
'Обработка события Щелчок для командной кнопки Выход
Unload Form2
Unload Form3
End
End Sub
10. изменить код подпрограммы Graph,добавив в операторе вывода точки цвет, взяв его из свойства Form1.cdb.Color
В процедуре mnuViewFont_Click( ) необходимо обязательно задать параметр Flags.Он сообщает Visual Basic, что нужно отображать как шрифты True Top, так и любые другие установленные в системе экранные и принтерные шрифты.
Дата добавления: 2014-11-29; просмотров: 858;