Операции чтения и записи строк для текстового файла
Последовательный (строка за строкой) доступ к текстовому файлу обеспечивает объект TextStream. Методы этого объекта позволяют читать информацию из файла и записывать ее в него. Создается объект TextStream при открытии или создании текстового файла с помощью следующих методов:
· CreateTextFile объектов FileSystemObject и Folder;
· OpenTextFile объекта FileSystemObject;
· OpenAsTextStream объекта File.
Перечисленные ранее методы позволяют открывать файл в разных режимах ввода/вывода (за это отвечает параметр Iomode ) с использованием разных форматов (в соответствии со значением параметра Format ) (см. табл. 6.2, 6.3)
| Таблица 6.2. Параметр Iomode | ||||
| Константа | Значение | Описание | ||
| ForReading | Файл открывается только для чтения, записывать информацию в него нельзя | |||
| ForWriting | Файл открывается для записи. Если файл с таким именем уже существовал, то при новой записи его содержимое теряется | |||
| ForAppending | Файл открывается для добавления. Если файл уже существовал, то информация будет дописываться в конец этого файла | |||
| Таблица 6.3. Параметр Format | ||||
| Константа | Значение | Описание | ||
| TristateUseDefault | -2 | Файл открывается в формате, используемом системой по умолчанию | ||
| TristateTrue | -1 | Файл открывается в формате Unicode | ||
| TristateFalse | Файл открывается в формате ASCII | |||
В листинге 6.10 приведен сценарий TextFile.vbs, в котором создается файл test1.txt и в него записываются строка текста. После этого файл открывается для чтения, строка считывается из него и выводится на экран.
'*******************************************************************
' Имя: TextFile.vbs
' Язык: VBScript
' Описание: Запись строк в текстовый файл и чтение из него
'*******************************************************************
Dim FSO,F,TextStream,s 'Объявляем переменные
' Инициализируем константы
Const ForReading = 1, ForWriting = 2, TristateUseDefault = -2
' Создаем объект FileSystemObject
Set FSO=WScript.CreateObject("Scripting.FileSystemObject")
' Создаем в текущем каталоге файл test1.txt
FSO.CreateTextFile "test1.txt"
' Создаем объект File для файла test1.txt
set F=FSO.GetFile("test1.txt")
' Создаем объект TextStream (файл открывается для записи)
Set TextStream=F.OpenAsTextStream(ForWriting, TristateUseDefault)
' Записываем в файл строку
TextStream.WriteLine "Это первая строка"
' Закрываем файл
TextStream.Close
' Открываем файл для чтения
Set TextStream=F.OpenAsTextStream(ForReading, TristateUseDefault)
' Считываем строку из файла
s=TextStream.ReadLine
' Закрываем файл
TextStream.Close
' Отображаем строку на экране
WScript.Echo "Первая строка из файла test1.txt:" & vbCrLf & vbCrLf & s
'************* Конец *********************************************
Листинг 6.10. Запись информации в текстовый файл и чтение из него (VBScript)
Дата добавления: 2018-03-01; просмотров: 471;